ps2_f_inf.gms : Parts Supply Problem w/ Inefficient Type w/o Asymmetric Information

Description

```Hideo Hashimoto, Kojun Hamada, and Nobuhiro Hosoe, "A Numerical Approach
to the Contract Theory: the Case of Adverse Selection", GRIPS Discussion
Paper 11-27, National Graduate Institute for Policy Studies, Tokyo, Japan,
March 2012.

Keywords: nonlinear programming, contract theory, principal-agent problem,
```

Small Model of Type : NLP

Category : GAMS Model library

Main file : ps2_f_inf.gms

``````\$title Parts Supply Problem w/ Inefficient Type w/o Asymmetric Information (PS2_F_inf,SEQ=361)

\$onText
Hideo Hashimoto, Kojun Hamada, and Nobuhiro Hosoe, "A Numerical Approach
to the Contract Theory: the Case of Adverse Selection", GRIPS Discussion
Paper 11-27, National Graduate Institute for Policy Studies, Tokyo, Japan,
March 2012.

Keywords: nonlinear programming, contract theory, principal-agent problem,
\$offText

option limCol = 0, limRow = 0;

Set i 'type of supplier' / inf /;

Parameter theta(i) 'efficiency' / inf 0.3 /;

Positive Variable
x(i) "quality"
b(i) "maker's revenue"
c(i) "cost";

Variable Util "maker's utility";

Equation
obj    "maker's utility function"
rev(i) "maker's revenue function"
pc(i)  "participation constraint";

obj..    Util =e= sum(i, (b(i) - c(i)));

rev(i).. b(i) =e= x(i)**(0.5);

pc(i)..  c(i) - theta(i)*x(i) =e= 0;

* Setting Lower Bounds on Variables to Avoid Division by Zero
x.lo(i) = 0.0001;

Model FB1 / all /;

solve FB1 maximizing Util using nlp;

Parameter
db(i) 'derivative of b'
w(i)  'price';

db(i) = 0.5*x.l(i)**(-0.5);
w(i)  = c.l(i);

display x.l, b.l, c.l, util.l, db, w;
``````
GAMS Development Corp.
GAMS Software GmbH

General Information and Sales
U.S. (+1) 202 342-0180
Europe: (+49) 221 949-9170